使用Terraform創建開啟自動伸縮功能的節點池

1. 修改集群的autoscaler-meta配置項。

   1. 登錄容器服務管理控制臺，在左側導航欄選擇集群。

   2. 在集群列表頁面，單擊目標集群名稱，然后在左側導航欄，選擇配置管理 > 配置項。

   3. 在配置項頁面左上角的命名空間下拉框中，選擇kube-system，然后在autoscaler-meta配置項右側操作列下，單擊編輯。

   4. 在編輯面板中，修改autoscaler-meta配置項的值。

      您需將taints值的String類型改成數組類型，即在值文本框中，修改"taints":""為"taints":[]。

   5. 單擊確定。

2. 同步節點池。

   1. 在集群管理頁左側導航欄，選擇節點管理 > 節點池。

   2. 在節點池頁面右上方，單擊同步節點池。

3. 使用Terraform創建開啟自動伸縮功能的節點池。

   1. 創建節點池的配置文件。

      • 在已有集群中創建開啟自動伸縮功能的節點池，配置示例如下。

        展開查看配置示例

        provider "alicloud" {
        }
        # 為已有集群創建開啟自動伸縮功能的節點池。
        resource "alicloud_cs_kubernetes_node_pool" "at1" {
          # 目標集群ID。
          cluster_id           = ""
          name                 = "np-test"
          # 節點池內節點使用的vswitch，至少提供一個。
          vswitch_ids          = ["vsw-bp1mdigyhmilu2h4v****"]
          instance_types       = ["ecs.e3.medium"]
          password             = "Hello1234"
         
          scaling_config {
            # 最小節點數。
            min_size     = 1
            # 最大節點數。
            max_size     = 5
          }
        
        }

      • 如果未創建集群，創建節點池的配置示例如下，需要先創建集群，然后才能創建節點池。

        展開查看配置示例

        provider "alicloud" {
        }
        
        variable "name" {
          default    = "tf-test"
        }
        
        data "alicloud_zones" default {
          available_resource_creation  = "VSwitch"
        }
        data "alicloud_instance_types" "default" {
          availability_zone            = data.alicloud_zones.default.zones.0.id
          cpu_core_count               = 2
          memory_size                  = 4
          kubernetes_node_role         = "Worker"
        }
        
        resource "alicloud_vpc" "default" {
          name                         = var.name
          cidr_block                   = "10.1.0.0/21"
        }
        resource "alicloud_vswitch" "default" {
          name                         = var.name
          vpc_id                       = alicloud_vpc.default.id
          cidr_block                   = "10.1.1.0/24"
          availability_zone            = data.alicloud_zones.default.zones.0.id
        }
        resource "alicloud_key_pair" "default" {
          key_name                     = var.name
        }
        
        # 創建托管版集群。
        resource "alicloud_cs_managed_kubernetes" "default" {
          name                         = var.name
          count                        = 1
          cluster_spec                 = "ack.pro.small"
          is_enterprise_security_group = true
          worker_number                = 2
          password                     = "Hello1234"
          pod_cidr                     = "172.20.0.0/16"
          service_cidr                 = "172.21.0.0/20"
          worker_vswitch_ids           = [alicloud_vswitch.default.id]
          worker_instance_types        = [data.alicloud_instance_types.default.instance_types.0.id]
        }
        
        # 為集群創建一個開啟自動伸縮功能的節點池。
        resource "alicloud_cs_kubernetes_node_pool" "at1" {
          cluster_id                   = alicloud_cs_managed_kubernetes.default.0.id
          name                         = var.name
          vswitch_ids                  = [alicloud_vswitch.default.id]
          instance_types               = [data.alicloud_instance_types.default.instance_types.0.id]
          key_name                     = alicloud_key_pair.default.key_name
         
          scaling_config {
            min_size     = 1
            max_size     = 5
          }
        
        }

   2. 執行terraform apply命令完成創建。

   完成創建節點池后，在節點池列表中可以看到新建的節點池，該節點池名稱下會標注已開啟自動伸縮。